
**Year-to-date over the full previous year**

The year-to-date over the full previous year compares the year-to-date against the entire previous year.

PYC-previous year comparison

YTDOPY-Year to date over previous year



The year-to-date-over-previous-year growth is computed by the Sales YTDOPY and Sales YTDOPY % measures; these rely on the Sales YTD measure to compute the year-to-date value, and on the Sales PYC measure to get the sales amount of the entire previous year:

Sales PYC :=

VAR CurrentYearNumber = SELECTEDVALUE ( 'Date'[Year] )

VAR PreviousYearNumber = CurrentYearNumber - 1

VAR Result =

    CALCULATE (

        [Sales Amount],

        REMOVEFILTERS ( 'Date' ),

        'Date'[Year] = PreviousYearNumber

    )

RETURN

    Result

Sales YTDOPY :=

VAR ValueCurrentPeriod = [Sales YTD]

VAR ValuePreviousPeriod = [Sales PYC]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod ) && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales YTDOPY % :=

DIVIDE (

    [Sales YTDOPY],

    [Sales PYC]

)

or

Sales PYC :=

IF (

    [ShowValueForDates] && HASONEVALUE ( 'Date'[Year] ),

    CALCULATE (

        [Sales Amount],

        PARALLELPERIOD ( 'Date'[Date], -1, YEAR )

    )

)

Sales YTDOPY :=

VAR ValueCurrentPeriod = [Sales YTD]

VAR ValuePreviousPeriod = [Sales PYC]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales YTDOPY % :=

DIVIDE (

    [Sales YTDOPY],

    [Sales PYC]

)

The Sales PYC measure can also be written using [**PREVIOUSYEAR**](https://dax.guide/previousyear/?aff=dax-patterns), whose behavior is similar to [**PARALLELPERIOD**](https://dax.guide/parallelperiod/?aff=dax-patterns) (the difference is not relevant for this example):

Sales PYC (2) :=

IF (

    [ShowValueForDates] && HASONEVALUE ( 'Date'[Year] ),

    CALCULATE (


        [Sales Amount],

        PREVIOUSYEAR ( 'Date'[Date] )

    )

)

[**PREVIOUSYEAR**](https://dax.guide/previousyear/?aff=dax-patterns) is mandatory if the comparison uses the fiscal year because [**PREVIOUSYEAR**](https://dax.guide/previousyear/?aff=dax-patterns) accepts a second argument to specify the last day of the fiscal year. Look at the following report in Figure 13, which is slicing the measures by fiscal periods.



The measures used in the report are defined as follows. Please pay attention to the second argument of [**PREVIOUSYEAR**](https://dax.guide/previousyear/?aff=dax-patterns) in Sales Fiscal PYC:

Sales Fiscal PYC :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales Amount],

        PREVIOUSYEAR ( 'Date'[Date], "06-30" )

    )

)

Sales Fiscal YTDOPY :=

VAR ValueCurrentPeriod = [Sales Fiscal YTD]

VAR ValuePreviousPeriod = [Sales Fiscal PYC]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales Fiscal YTDOPY % :=

DIVIDE (

    [Sales Fiscal YTDOPY],

    [Sales Fiscal PYC]

)